%{
#include <iostream>
#include <string>
#include <cstdlib>
#include "izraz.hpp"
#include "naredba.hpp"
#define YYDEBUG 1
#include <vector>
  
using namespace std;

 void yyerror(string s) {
   cerr << s << endl;
   exit(EXIT_FAILURE);
 }

 extern int yylex();
 
%}

%union {
  int v;
  Izraz *i;
  Naredba *n;
  string *s;
  vector<Naredba*> *niz;
}

%token ispisi_token pocetak_token mod_token kraj_token dodela_token ako_je_token onda_token inace_token unesi_token dok_je_token radi_sledece_token
%token <v> num_token
%token <s> string_token id_token

%type <i> E
%type <n> Naredba Blok
%type <niz> NizNaredbi

%nonassoc ':'
%nonassoc inace_token
%left '<' '>'
%left '+' '-'
%left '*' '/' mod_token

%%
Program: Blok '.' {
  $1->izvrsi();
  delete $1;
 }
;

Blok: pocetak_token NizNaredbi kraj_token {
  $$ = new Blok(*$2);
  delete $2;
 }
;

NizNaredbi: NizNaredbi ';' Naredba {
  $$ = $1;
  $$->push_back($3);
 }
| Naredba {
  $$ = new vector<Naredba*>();
  $$->push_back($1);
 }
;

Naredba: ispisi_token '(' string_token ')' {
  $$ = new IspisS(*$3);
  delete $3;
 }
| ispisi_token '(' E ')' {
  $$ = new IspisE($3);
  delete $3;
 }
| id_token dodela_token E {
  $$ = new Dodela(*$1, $3);
  delete $1;
  delete $3;
 }
| unesi_token '(' id_token ')' {
  $$ = new Unos(*$3);
  delete $3;
  }
| ako_je_token E onda_token ':' Naredba inace_token ':' Naredba {
  $$ = new AkoJeOndaInace($2, $5, $8);
  delete $2;
  delete $5;
  delete $8;
 }
| ako_je_token E onda_token ':' Naredba {
  $$ = new AkoJeOndaInace($2, $5, new Prazna());
  delete $2;
  delete $5;
 }
| dok_je_token E radi_sledece_token ':' Naredba {
  $$ = new DokJe($2, $5);
  delete $2;
  delete $5;
 }
| Blok {
  $$ = $1;
  }
;

E: E '+' E {
  $$ = new Zbir($1, $3);
  delete $1;
  delete $3;
 }
| E '-' E {
  $$ = new Razlika($1, $3);
  delete $1;
  delete $3;
 }
| E '*' E {
  $$ = new Proizvod($1, $3);
  delete $1;
  delete $3;
 }
| E '/' E {
  $$ = new Kolicnik($1, $3);
  delete $1;
  delete $3;
 }
| E mod_token E {
  $$ = new Mod($1, $3);
  delete $1;
  delete $3;
 }
| E '<' E {
  $$ = new Manje($1, $3);
  delete $1;
  delete $3;
 }
| E '>' E {
  $$ = new Vece($1, $3);
  delete $1;
  delete $3;
 }
| '(' E ')' {
  $$ = $2;
 }
| num_token  {
  $$ = new Konstanta($1);
 }
| id_token {
  $$ = new Promenljiva(*$1);
  delete $1;
  }
;
%%

extern FILE *yyin;

int main(int argc, char **argv) {
  if (argc < 2)
    yyerror("Program se poziva sa jednim argumentom");
  if ((yyin = fopen(argv[1], "r")) == NULL)
    yyerror("Neuspesno otvaranje fajla sa pascal kodom");
  //yydebug = 1;
  yyparse();
  fclose(yyin);
  return 0;
}