%{

  #include <iostream>
  #include <string>
  #include <cstdlib>
  #include <vector>
  #include "izrazi.hpp"
  #include "naredbe.hpp"
  #include <map>
  #include <cstdio>
  #define YYDEBUG 1
  using namespace std;
  
  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }

  extern int yylex();

  map<string, int> tablica;

  bool nazubi = false;
 
%}

%token ispisi_token pocetak_token kraj_token mod_token unesi_token ako_je_token onda_token inace_token dok_je_token radi_sledece_token
%token <d> num_token
%token <s> string_token id_token

%nonassoc ':'
%nonassoc inace_token
%left '<' '>'
%left '+' '-'
%left '*' '/' mod_token

%type <i> E
%type <n> Naredba Blok
%type <v> NizNaredbi

%union {
  int d;
  Izraz *i;
  Naredba *n;
  string *s;
  vector<Naredba*> *v;
}

%%
Program: Blok '.' {
  if (nazubi == false)
    $1->izvrsi();
  else {
    $1->nazubi(0);
    cout << "." << endl;
  }
  delete $1;
 }
;

Blok: pocetak_token NizNaredbi kraj_token {
  $$ = new Blok(*$2);
  delete $2;
 }
;

NizNaredbi: NizNaredbi ';' Naredba {
  $$ = $1;
  $$->push_back($3);
 }
| Naredba {
  $$ = new vector<Naredba*>();
  $$->push_back($1);
 }
;

Naredba: ispisi_token '(' string_token ')' {
  $$ = new IspisS(*$3);
  delete $3;
 }
| ispisi_token '(' E ')' {
  $$ = new IspisE($3);
 }
| id_token ':' '=' E {
  $$ = new Dodela(*$1, $4);
  delete $1;
  }
| unesi_token '(' id_token ')' {
  $$ = new Unos(*$3);
  delete $3;
  }
| ako_je_token E onda_token ':' Naredba inace_token ':' Naredba {
  $$ = new AkoJeOndaInace($2, $5, $8);
 }
| ako_je_token E onda_token ':' Naredba {
  $$ = new AkoJeOnda($2, $5);
 }
| Blok {
  $$ = $1;
  }
| dok_je_token E radi_sledece_token ':' Naredba {
  $$ = new DokJe($2, $5);
 }
;

E: E '+' E {
  $$ = new Zbir($1, $3);
 }
| E '-' E {
  $$ = new Razlika($1, $3);
  }
| E '*' E {
  $$ = new Proizvod($1, $3);
  }
| E '/' E {
  $$ = new Kolicnik($1, $3);
  }
| E mod_token E {
  $$ = new Mod($1, $3);
  }
| E '<' E {
  $$ = new Manje($1, $3);
  }
| E '>' E {
  $$ = new Vece($1, $3);
  }
| '(' E ')' {
  $$ = $2;
  }
| num_token {
  $$ = new Konstanta($1);
  }
| id_token {
  $$ = new Promenljiva(*$1);
  delete $1;
  }
;

%%

extern FILE* yyin;

int main(int argc, char **argv) {
  
  //yydebug = 1;

  if (argc < 2)
    yyerror("Neispravno pozivanje programa");

  if (argc > 2 && string(argv[1]) == "--nazubi")
    nazubi = true;

  if ((yyin = fopen(argv[argc-1], "r")) == NULL)
    yyerror("Neuspesno otvaranje fajla sa programom");
  
  yyparse();

  fclose(yyin);
  
  return 0;
}