%{

#include <iostream>
#include <string>
#include <cstdlib>
#include <vector>
#include "regex.hpp"
  using namespace std;

  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }

  extern int yylex();
  
%}

%union {
  char c;
  vector<char> *v;
  RegEx *r;
}

%token basic_token
%token <c> char_token

%type <v> NizKaraktera
%type <r> E T F

%%
Program: Program Naredba '\n'
| Naredba '\n'
;

Naredba: basic_token E {
  $2->basic();
  cout << endl;
  delete $2;
 }
;

E: E '|' T {
  $$ = new Disjunkcija($1, $3);
 }
| T {
  $$ = $1;
 }
;
T: T F {
  $$ = new Konkatenacija($1, $2);
 }
| F {
  $$ = $1;
 }
;
F: F '*' {
  $$ = new Klini($1);
 }
| F '+' {
  $$ = new Plus($1);
 }
| F '?' {
  $$ = new Upitnik($1);
 }
| char_token {
  $$ = new Slovo($1);
 }
| '(' E ')' {
  $$ = $2;
 }
| '[' NizKaraktera ']' {
  $$ = new KarakterskaKlasa(*$2);
  delete $2;
 }
;

NizKaraktera: NizKaraktera char_token {
  $$ = $1;
  $$->push_back($2);
 }
| char_token {
  $$ = new vector<char>();
  $$->push_back($1);
 }
;

%%
int main() {
  yyparse();
  return 0;
}