%{
#include <iostream>
#include <string>
#include <cstdlib>
#include "ast.hpp"
#define YYDEBUG 1
  using namespace std;

  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }

  int yylex();

%}

%left '+' '-'
%left '*' '/'

%union {
  double d;
  string *s;
  ExprAST *e;
  vector<ExprAST*> *v;
  vector<string> *v1;
  PrototypeAST *p;
}

%type <e> E
%type <v> NizE
%type <v1> Argumenti
%type <p> Potpis

%token def_token extern_token
%token <s> id_token
%token <d> num_token

%%
Program: Program Naredba ';'
| Naredba ';'
;
Naredba: def_token Potpis E {
  FunctionAST f(*$2, $3);
  delete $2;
  f.codegen();
 }
| extern_token Potpis {
  $2->codegen();
  delete $2;
 }
| E {
  //TODO:
 }
; 
Potpis: id_token '(' Argumenti ')' {
  $$ = new PrototypeAST(*$1, *$3);
  delete $1;
  delete $3;
 }
;
Argumenti: Argumenti id_token {
  $$ = $1;
  $$->push_back(*$2);
  delete $2;
 }
|  {
  $$ = new vector<string>();
 }
;
E: E '+' E {
  $$ = new AddExprAST($1, $3);
 }
| E '-' E {
  $$ = new SubExprAST($1, $3);
 }
| E '*' E {
  $$ = new MulExprAST($1, $3);
 }
| E '/' E {
  $$ = new DivExprAST($1, $3);
 }
| '(' E ')' {
  $$ = $2;
 }
| num_token {
  $$ = new NumberExprAST($1);
 }
| id_token {
  $$ = new VariableExprAST(*$1);
  delete $1;
 }
| id_token '(' NizE ')' {
  $$ = new CallExprAST(*$1, *$3);
  delete $1;
  delete $3;
  }
| id_token '(' ')' {
  $$ = new CallExprAST(*$1, vector<ExprAST*>());
  delete $1;
  }
;
 NizE: NizE ',' E {
  $$ = $1;
  $$->push_back($3);
  }
| E {
  $$ = new vector<ExprAST*>();
  $$->push_back($1);
  }
;
%%

extern LLVMContext TheContext;
extern Module *TheModule;

int main() {
  //yydebug = 1;

  TheModule = new Module("Moj modul", TheContext);
  yyparse();
  TheModule->dump();
  delete TheModule;
  
  return 0;
}