%{
#include <string>
#include <iostream>
#include <cstdlib>
#include "regex.hpp"
#include <vector>
  using namespace std;
  
  extern int yylex();

  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }

  
%}

%union {
  char c;
  RegEx *r;
  vector<char> *v;
  int i;
}

%token basic_token
%token <c> slovo_token
%token <i> num_token

%type <r> E T F
%type <v> NizSlova


%%
Program: Program Naredba '\n'
| Naredba '\n'
;
Naredba: basic_token E {
  cout << $2->basic() << endl;
  delete $2;
 }
;
E: E '|' T {
  $$ = new Disjunkcija($1, $3);
 }
|  T {
  $$ = $1;
 }
;
T: T F {
  $$ = new Konkatenacija($1, $2);
 }
|  F {
  $$ = $1;
 }
;
F: F '*' {
  $$ = new Klini($1);
 }
|  '(' E ')' {
  $$ = $2;
 }
|  slovo_token {
  $$ = new Slovo($1);
 }
| F '+' {
  $$ = new Plus($1);
  }
| '[' NizSlova ']' {
  $$ = new KarakterskaKlasa(*$2);
  delete $2;
  }
| F '?' {
  $$ = new Upitnik($1);
  }
| F '{' num_token '}' {
  $$ = new VisetrukoPojavljivanje($1, $3);
  }
;
NizSlova: NizSlova slovo_token {
  $$ = $1;
  $$->push_back($2);
 }
| slovo_token {
  $$ = new vector<char>();
  $$->push_back($1);
 }
;
%%

int main(int argc, char **argv) {
  yyparse();

  return 0;
}