%{
#include <string>
#include <iostream>
#include <cstdlib>
#include "funkcije.hpp"
#include <map>
  using namespace std;
  
  extern int yylex();

  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }

  map<char, Funkcija*> tablica;
  
%}

%union {
  Funkcija *f;
  double d;
  char c;
}

%token function_token sin_token cos_token
%token <c> id_token
%token <d> num_token

%type <f> E

%left '+' '-'
%left '*' '/'
%nonassoc '\''

%%
Program: Program Naredba '\n'
| Naredba '\n'
;
Naredba: function_token id_token '=' '"' E '"' {
  map<char, Funkcija*>::iterator i = tablica.find($2);
  if (i != tablica.end())
    delete i->second;

  tablica[$2] = $5;
 }
| id_token {
  map<char, Funkcija*>::iterator i = tablica.find($1);
  if (i == tablica.end())
    yyerror("Nedefinisana fja");

  i->second->ispisi();
  cout << endl;
  }
| id_token '\'' {
  map<char, Funkcija*>::iterator i = tablica.find($1);
  if (i == tablica.end())
    yyerror("Nedefinisana fja");
  Funkcija* izvod = i->second->izvod();
  izvod->ispisi();
  cout << endl;
  delete izvod;
  }
| id_token '[' num_token ']' {
  map<char, Funkcija*>::iterator i = tablica.find($1);
  if (i == tablica.end())
    yyerror("Nedefinisana fja");
  cout << i->second->vrednost($3)<<endl;
  }
;
E: E '+' E {
  $$ = new Zbir($1, $3);
 }
|  E '-' E {
  $$ = new Razlika($1, $3);
 }
|  E '*' E {
  $$ = new Proizvod($1, $3);
 }
|  E '/' E {
  $$ = new Kolicnik($1, $3);
 }
|  sin_token '(' E ')' {
  $$ = new Sin($3);
 }
|  cos_token '(' E ')' {
  $$ = new Cos($3);
 }
|  '(' E ')' {
  $$ = $2;
 }
|  num_token {
  $$ = new Konstanta($1);
 }
|  'x' {
  $$ = new IdFja();
 }
| E '\'' {
  $$ = $1->izvod();
  //TODO: dodati metod kopija u izvodu za proizvod, kolicnik, sin i cos
  //delete $1;
  }
;
%%

int main(int argc, char **argv) {
  yyparse();

  //TODO: dodati metod kopija
  //for (map<char, Funkcija*>::iterator i = tablica.begin(); i != tablica.end(); i++)
  //  delete i->second;
  
  return 0;
}