%{
#include <iostream>
#include <string>
#include <cstdlib>
#include "syn_tree.hpp"
#include <vector>
#define YYDEBUG 1
  
  using namespace std;

  int yylex();

  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }
  
%}

%union {
  int i;
  string *s;
  SynTree *t;
  vector<SynTree*> *v;
}

%nonassoc then_token
%nonassoc else_token

%left '<' '>'
%left '+' '-'
%left '*' '/'

%token begin_token end_token print_token while_token do_token if_token then_token else_token
%token <i> num_token
%token <s> id_token

%type <t> E Naredba Blok
%type <v> Niz

%%
Program: Blok '.' {
  $1->compile();
  delete $1;
 }
;
Blok: begin_token Niz end_token {
  $$ = new Seq(*$2);
  delete $2;
 }
;
Niz: Niz ';' Naredba {
  $$ = $1;
  $$->push_back($3);
 }
| Naredba {
  $$ = new vector<SynTree*>();
  $$->push_back($1);
 }
;
Naredba: id_token ':' '=' E {
  $$ = new Assign(new Variable(*$1), $4);
  delete $1;
 }
| print_token E {
  $$ = new Print($2);
 }
| while_token E do_token Naredba {
  $$ = new While($2, $4);
 }
| Blok {
  $$ = $1;
  }
|  {
  $$ = new Eps();
  }
| if_token E then_token Naredba else_token Naredba {
  $$ = new IfThenElse($2, $4, $6);
 }
| if_token E then_token Naredba {
  $$ = new IfThen($2, $4);
 }
;
E: E '+' E {
  $$ = new Add($1, $3);
 }
| E '-' E {
  $$ = new Sub($1, $3);
 }
| E '*' E {
  $$ = new Mul($1, $3);
 }
| E '/' E {
  $$ = new Div($1, $3);
 }
| E '>' E {
  $$ = new Greater($1, $3);
 }
| E '<' E {
  $$ = new Less($1, $3);
 }
| '(' E ')' {
  $$ = $2;
 }
| num_token {
  $$ = new Constant($1);
 }
| id_token {
  $$ = new Variable(*$1);
  delete $1;
 }
;
%%
int main() {
  //yydebug = 1;
  yyparse();
  return 0;
}