%{

#include <iostream>
#include <string>
#include <cstdlib>
#include <vector>
#include "ast.hpp"
#define YYDEBUG 1  
  using namespace std;

  int yylex();

  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }

  int counter = 0;
  
%}

%union {
  double d;
  string *s;
  ExprAST *e;
  vector<ExprAST*> *v;
  vector<string> *v1;
  PrototypeAST *p;
  pair<string, ExprAST*> *p1;
  vector<pair<string, ExprAST*> > *v2;
}

%token def_token extern_token if_token then_token else_token for_token in_token var_token
%token <s> id_token
%token <d> num_token

%type <e> E
%type <v> Arguments Arguments1
%type <v1> Args
%type <p> Potpis
%type <p1> Inic
%type <v2> NizInic

%left ':'
%nonassoc else_token in_token
%left '<' '>'
%left '+' '-'
%left '*' '/'

%%
Program: Program Statement ';' {

 }
| Statement ';' {

 }
;
Statement: def_token Potpis E {
  FunctionAST *f = new FunctionAST(*$2, $3);
  delete $2;
  f->codegen();
  delete f;
 }
| E {
  PrototypeAST p(to_string(counter++), vector<string>());
  FunctionAST *f = new FunctionAST(p, $1);
  f->codegen();
  delete f;
 }
| extern_token Potpis {
  $2->codegen();
  delete $2;
  }
;
Potpis: id_token '(' Args ')' {
  $$ = new PrototypeAST(*$1, *$3);
  delete $1;
  delete $3;
 }
;
Args: Args id_token {
  $$ = $1;
  $$->push_back(*$2);
  delete $2;
 }
| {
  $$ = new vector<string>();
 }
;
E: E '+' E {
  $$ = new AddExprAST($1, $3);
 }
| E '-' E {
  $$ = new SubExprAST($1, $3);
 }
| E '*' E {
  $$ = new MulExprAST($1, $3);
 }
| E '/' E {
  $$ = new DivExprAST($1, $3);
 }
| E '>' E {
  $$ = new GtExprAST($1, $3);
  }
| E '<' E {
  $$ = new LtExprAST($1, $3);
  }
| E ':' E {
  $$ = new SeqExprAST($1, $3);
  }
| '(' E ')' {
  $$ = $2;
 }
| id_token {
  $$ = new VariableExprAST(*$1);
  delete $1;
 }
| num_token {
  $$ = new NumberExprAST($1);
 }
| id_token Arguments {
  $$ = new CallExprAST(*$1, *$2);
  delete $1;
  delete $2;
 }
| if_token E then_token E else_token E {
  $$ = new IfExprAST($2, $4, $6);
 }
| for_token id_token '=' E ',' E ',' E in_token E {
  $$ = new ForExprAST(*$2, $4, $6, $8, $10);
  delete $2;
 }
| for_token id_token '=' E ',' E in_token E {
  $$ = new ForExprAST(*$2, $4, $6, NULL, $8);
  delete $2;
 }
| var_token NizInic in_token E {
  $$ = new VarExprAST(*$2, $4);
  delete $2;
 }
;
NizInic: NizInic ',' Inic {
  $$ = $1;
  $$->push_back(*$3);
  delete $3;
}
| Inic {
  $$ = new vector<pair<string, ExprAST*> >();
  $$->push_back(*$1);
  delete $1;
}
;
Inic: id_token '=' E {
  $$ = new pair<string, ExprAST*>(*$1, $3);
  delete $1;
}
| id_token {
  $$ = new pair<string, ExprAST*>(*$1, NULL);
  delete $1;  
}
;
Arguments: '(' ')' {
  $$ = new vector<ExprAST*>();
 }
| '(' Arguments1 ')' {
  $$ = $2;
 }
;
Arguments1: Arguments1 ',' E {
  $$ = $1;
  $$->push_back($3);
 }
| E {
  $$ = new vector<ExprAST*>();
  $$->push_back($1);
 }
;
%%

extern Module* TheModule;
extern LLVMContext TheContext;

int main() {
  //yydebug = 1;
  InitializeModuleAndPassManager();
  yyparse();
  TheModule->dump();
  delete TheModule;
  return 0;
}