%{
#include <iostream>
#include <cstdlib>
#include <string>
#include <map>
#include <cstdio>

#include "izraz.hpp"
#include "naredba.hpp"

#define YYDEBUG 1
  using namespace std;
 
  extern int yylex();
  
  void yyerror(string s) {
    cerr << s << endl;
    exit(EXIT_FAILURE);
  }

  extern map<string, int> tablica;
 
%}

%union {
  int i;
  string *s;
  Izraz *iz;
  Naredba *n;
  vector<Naredba*> *v;
}

%token pocetak_token kraj_token ispisi_token mod_token unesi_token ako_je_token inace_token onda_token
%token <i> broj_token
%token <s> string_token id_token

%left ':'
%left inace_token

%left '<' '>'
%left '+' '-'
%left '*' '/' mod_token


%type <iz> E
%type <n> Naredba Blok
%type <v> NizNaredbi

%%
Program: Blok '.' {
  $1->izvrsi();
  delete $1;
 }
;
Blok: pocetak_token NizNaredbi kraj_token {
  $$ = new Blok(*$2);
  delete $2;
 }
;
NizNaredbi: NizNaredbi  ';' Naredba {
  $1->push_back($3);
  $$ = $1;
 }
| Naredba {
  $$ = new vector<Naredba*>();
  $$->push_back($1);
 }
;
Naredba: ispisi_token '(' string_token ')' {
  $$ = new IspisStringa(*$3);
  delete $3;
 }
| ispisi_token '(' E ')' {
  $$ = new IspisIzraza($3);
  delete $3;
 }
| id_token ':' '=' E {
  $$ = new Dodela(*$1, $4);
  delete $1;
  delete $4;
  }
| unesi_token '(' id_token ')' {
  $$ = new Unesi(*$3);
  delete $3;
}
| ako_je_token E onda_token ':' Naredba {
  $$ = new AkoJeOnda($2, $5);
  delete $2;
 }
| ako_je_token E onda_token ':' Naredba inace_token ':' Naredba {
  $$ = new AkoJeOndaInace($2, $5, $8);
  delete $2;
 }
;
E: E '+' E {
  $$ = new Zbir($1, $3);
  delete $1;
  delete $3;
 }
| E '-' E {
  $$ = new Razlika($1, $3);
  delete $1;
  delete $3;
 }
| E '*' E {
  $$ = new Proizvod($1, $3);
  delete $1;
  delete $3;
 }
| E '/' E {
  $$ = new Kolicnik($1, $3);
  delete $1;
  delete $3;
 }
| E mod_token E {
  $$ = new Mod($1, $3);
  delete $1;
  delete $3;
 }
| E '<' E {
  $$ = new Manje($1, $3);
  delete $1;
  delete $3;
  }
| E '>' E {
  $$ = new Vece($1, $3);
  delete $1;
  delete $3;
  }
| '(' E ')' {
  $$ = $2;
  /*
    $$ = $2->kopija();
    delete $2;
  */
  }
| broj_token {
  $$ = new Konstanta($1);
 }
| id_token {
  $$ = new Promenljiva(*$1);
  delete $1;
  }
;
%%
int main(int argc, char **argv) {

  extern FILE* yyin;
  
  if (argc != 2)
    yyerror(string("usage: ") + argv[0] + " pascal_datoteka");
  if ((yyin = fopen(argv[1], "r")) == NULL)
    yyerror(string("Nemoguce otvoriti datoteku ") + argv[1]);
    
  //yydebug = 1;
  yyparse();

  fclose(yyin);
  
  return 0;
}